FSR - QBasic Seite 12

AG Informatik

Der mächtigste Schleifen-Typ ist die DO...LOOP-Schleife. Bei DO...LOOP-Schleifen kann die Abbruchbedingung zu Beginn der Schleife (z.B. DO WHILE a<4 oder DO UNTIL a$="Ende") oder am Ende der Schleife (z.B. LOOP WHILE a<7 oder LOOP UNTIL a$<>"Ende") geprüft werden. Eine DO...LOOP-Schleife kann auch im Inneren der Schleife verlassen werden, z.B. durch IF a=9 THEN EXIT DO.

Das folgende Programm verwendet den Grafikmodus (SCREEN 12). Der Bildschirm ist dabei in 640 mal 480 Bildpunkte (Pixel) aufgeteilt. Die obere linke Ecke hat die Koordinaten 0,0; die untere rechte Ecke die Koordinaten 639,479.
Ein Punkt kann gesetzt werden mit Hilfe des Befehls PSET (x,y),farbe.

       REM Stars
       CLS
       SCREEN 12
       LINE (0, 0)-(639, 459), 15, B
       RANDOMIZE TIMER
       sterne = 0
       maxSterne=5000
       DO
         sterne = sterne + 1
         x = 2 + RND * 636
         y = 2 + RND * 456
         farbe = 1 + RND * 15
         PSET (x, y), farbe
       LOOP UNTIL sterne > maxSterne
       END

Das folgende Programm zeigt alle vier Möglichkeiten der DO...LOOP-Schleife.

       REM DL 1
       CLS
       SCREEN 12
       x = 1
       DO
         PSET (x, 0), 1 : x = x + 1
       LOOP WHILE x < 639
       INPUT nix$
       x = 1
       DO
         PSET (x, 459), 4 : x = x + 1
       LOOP UNTIL x > 638
       INPUT nix$
       y = 1
       DO WHILE y < 458
         PSET (0, y), 2 : y = y + 1
       LOOP
       INPUT nix$
       y = 1
       DO UNTIL y > 457
         PSET (639, y), 3 : y = y + 1
       LOOP