FSR - QBasic Seite 34

AG Informatik

Mit QBasic lassen sich durch entsprechende Befehle sehr einfach Rechtecke, Quadrate, Kreise und Ovale zeichnen. Bei den eckigen Figuren kann gewählt werden, ob sie leer oder gefüllt dargestellt werden soll.

Das folgende Programm zeichnet bei SCREEN 12 (640*480, 16 Farben) 20 verschiedene Rechtecke an zufälligen Bildschirmpositionen.

       REM Rechteck1
       RANDOMIZE TIMER
       SCREEN 12
       CLS
       FOR rechteck = 1 TO 20
         LET breite = INT(RND * 80) + 20
         LET hoehe = INT(RND * 80) + 20
         LET x1 = INT(RND * (640 - breite))
         LET y1 = INT(RND * (480 - hoehe))
         LET farbe = INT(RND * 15) + 1
         LINE (x1, y1)-(x1 + breite, y1 + hoehe), farbe, B
       NEXT rechteck
       a$ = ""
       WHILE a$ = ""
         a$ = INKEY$
       WEND

Ändere das obige Programm wie folgt ab:

         :
         LET y1 = INT(RND * (480 - hoehe))
         LET farbe = INT(RND * 15) + 1
         LET gefuellt = INT(RND *2)
         IF gefuellt = 0 THEN
           LINE (x1, y1)-(x1 + breite, y1 + hoehe), farbe, B
         ELSE
           LINE (x1, y1)-(x1 + breite, y1 + hoehe), farbe, BF
         END IF
       NEXT rechteck
       :

Das Programm erzeugt jetzt abhängig vom Wert der Variablen gefuellt (0 oder 1) ungefuellte oder gefuellte Rechtecke.

Versuche anhand des Programm-Listings folgende Frage zu beantworten.
1. Welches ist die minimale bzw. maximale Breite/Höhe eines Rechtecks?
2. Welches sind für jeden der 4 Fälle die minimalen bzw. maximalen Koordinaten der linken oberen Ecke des Rechtecks?
3. Welche Farbnummer ist die kleinste bzw. die größte?